.include "1200def.inc"

.equ MINPR = 1
.equ MAXPR = 20
.equ MINCH = 2
.equ MAXCH = 69
.equ MSGBSYTM = $ff	;Message busy time
.equ UHFBAS = $1fe2
.equ VHF3BAS = $0d62
.equ VHF1BAS = $0572
.equ SDAP = 6
.equ SCLP = 5

;***** Flags Bit Definitions ***** 
.equ KEYPR = 0
.equ CHANN = 1
.equ MSGBSY = 2
.equ NORPT = 3
.equ WUP = 4

;***** Scanr Bit Definitions *****
.equ DGT2 = 0
.equ DGT1 = 1

.def dig1 = r1
.def dig2 = r2
.def dig3 = r3
.def dig4 = r4
.def m1 = r5
.def m2 = r6
.def timr1 = r8
.def timr2 = r9
.def temp4 = r7
.def scanr = r16
.def temp1 = r17
.def temp2 = r18
.def temp3 = r19
.def code = r20
.def char = r21
.def key_no = r22
.def key_rpt = r23
.def ch_no = r24
.def flags = r25
.def rptcnt = r26
.def pr_no = r27
.def cnt1 = r28
.def cnt2 = r29
.def port3202 = r10
.def plladdr = r30

.cseg

.org $0000
	rjmp RESET

;****************************************************************************************
;* Startup Routine
;**************************************************************************************** 

INIT:	
	ldi	temp1,0b11111111	  ;Port B is an output port
	out 	DDRB,temp1
	ldi 	temp1,0b00010011	;b2, b3 of Port D are inputs
	out 	DDRD,temp1		    ;also b5, b6
	ldi 	temp1,0b00001101	;Pull up inputs of Port D, b5, b6 open collector
	mov 	scanr,temp1		    ;Start scan with pattern '01'
	out 	PORTD,scanr
	clr 	flags			        ;Reset flags
	ldi 	pr_no,2			      ;Set Program to 1
	mov 	temp2,pr_no
	rcall 	EERD			      ;Read channel of Program 1 from EEPROM
	mov 	ch_no,temp3
	mov 	cnt1,pr_no
	sbr 	flags,1<<CHANN		
  rcall 	CHPR		        ;Set system in channel mode
	clr timr1
	clr timr2
	ret

;*********************************************************************
;* Scan 2-Digit Display Routine
;*********************************************************************

SCAND:		
        bst scanr, DGT2	    ;Load to T flag the DGT2 (bit 0)
        brtc DG2		        ;If clear turn digit2 ON
        sbi PORTD, DGT2     ;Else turn off digit 2
        nop
        nop
        out PORTB, dig1     ;and turn ON digit 1
        nop
        nop
        out PORTD, scanr	  ;Enable digit 1
        cbr scanr,1<<DGT2	  ;Prepare scanr b0, b1 for next cycle
        sbr scanr,1<<DGT1
        rjmp EDG		        ;Exit from subroutine
DG2:	  sbi PORTD, DGT1	    ;Turn off digit 1
      	nop
        nop
        out PORTB, dig2	    ;and turn ON digit 2
        nop
        nop
        out PORTD, scanr	  ;Enable digit 2
        cbr scanr,1<<DGT1	  ;Prepare scanr b0, b1 for next cycle
        sbr scanr,1<<DGT2
EDG: 	  ret

;***********************************************************

CHRGEN:	
d0:	cpi code, 0
	brne d1
	ldi char, $3f

d1:	cpi code, 1
	brne d2
	ldi char, $06

d2:	cpi code, 2
	brne d3
	ldi char, $5b

d3:	cpi code, 3
	brne d4
	ldi char, $4f

d4:	cpi code, 4
	brne d5
	ldi char, $66

d5:	cpi code, 5
	brne d6
	ldi char, $6d

d6:	cpi code, 6
	brne d7
	ldi char, $7d

d7:	cpi code, 7
	brne d8
	ldi char, $07

d8:	cpi code, 8
	brne d9
	ldi char, $7f

d9:	cpi code, 9
	brne dflt
	ldi char, $6f
dflt:	ret

;*********************************************************

SCANK:	
	in 	key_no, PIND		;Διάβασε τα bit εισόδου από τη port D
	andi 	key_no, $0c		;Απομόνωσε τα bit εισόδου 00001100
	cpi 	key_no, $0c		;Εάν b2 & b3 = 1, δεν πατήθηκε πλήκτρο
	breq 	NOKEY
	nop				;Περίμενε για σταθεροποίηση της επαφής
	nop
	nop
	nop
	in 	temp1, PIND		;Ξαναδιάβασε τα bit εισόδου
	andi 	temp1, $0c
	cp 	key_no, temp1	
	brne 	NOKEY			;Αν δεν είναι το ίδιο τότε λάθος
	com 	key_no			;Αλλιώς κάνε αντιστροφή του κωδικού
	asr 	key_no			
	asr 	key_no			;Ολίσθησε 2 θέσεις δεξιά τον κωδικό
	andi 	key_no, 03		;Απομόνωσε τα b0 και b1
	cpi 	key_no, 03		;Αν είναι 3 τότε πατήθηκαν και τα 2 πληκτρα
	brne 	SC1			;της στήλης σάρωσης
	sbic 	PORTD, 1 		;Εαν σαρώνει τη 2η στήλη ο κωδικός του συνδιασμού
	ldi 	key_no, 6		;πλήκτρων είναι 6, αλλιώς παραμένει 3
SC1:	ldi 	temp1, 2		;Διαφορετικά έχει τιμές 1 ή 2
	sbis 	PORTD, 1		;Aν σαρώνει τη 2η στήλη πρόσθεσε 
	add 	key_no, temp1		;στη τιμή 2 (τιμές 3, 4) αλλιώς (τιμές 1, 2)
	cbr 	flags, 1<<KEYPR	;Πατήθηκε πλήκτρο
	ret
NOKEY:	ldi 	key_no, 0
	sbrc 	flags, KEYPR		;SKIP αν τη προηγούμενη φορά ήταν πατημένο 
	ldi 	key_rpt, 0		;Else το κουμπί σταμάτησε να πατιέται
	sbr 	flags, 1<<KEYPR	;Μια φορά δεν πατήθηκε πλήκτρο
	ret

;*********************************************************

FUNCT: cp key_no, key_rpt
	breq KPRSD
	clr rptcnt
	cbr flags, 1<<NORPT
	mov key_rpt, key_no
UP:	cpi key_no, 3
	brne DWN
	   rcall CNTUP
	   rcall BIN2BCD8
	   rcall PRINT	
DWN:	cpi key_no, 1
	brne MEM
	   rcall CNTDN
	   rcall BIN2BCD8
	   rcall PRINT	
MEM:	cpi key_no, 2
	brne CH_PR
	   sbr flags, 1<<NORPT
	   rcall STORE
CH_PR:	cpi key_no, 4
	brne SHFT
	  sbr flags, 1<<NORPT 
         rcall CHPR
SHFT:	cpi key_no, 6
	brne KPRSD
	nop
KPRSD:	cpi rptcnt, 35
	brne FU2
	ldi key_rpt, 0
	clr rptcnt	
	ret
FU2:	sbrs flags, NORPT
	inc rptcnt
	ret

;**********************************************************

CNTUP:	
	ldi temp1, MAXPR
	sbrs flags, CHANN	;If true the system entered in Program Mode
	ldi temp1, MAXCH	;Else system entered in Channel Mode
	cp cnt1, temp1
	breq CNU1
	inc cnt1	  
	rjmp MMNG
CNU1:	ldi temp1, MINPR
	sbrs flags, CHANN
	ldi temp1, MINCH
	mov cnt1, temp1
	rjmp MMNG

CNTDN:	
	ldi temp1, MINPR+1
	sbrs flags, CHANN
	ldi temp1, MINCH+1
	cp cnt1, temp1
	brmi CND1
	dec cnt1
	rjmp MMNG
CND1:	ldi temp1, MAXPR
	sbrs flags, CHANN
	ldi temp1, MAXCH
	mov cnt1, temp1
MMNG:	sbrc flags, CHANN
       mov pr_no, cnt1
	sbrs flags, CHANN
	mov ch_no, cnt1
	bst flags, CHANN
	brtc MM2 		
	mov temp2, pr_no
	rcall EERD
	mov ch_no, temp3		
MM2:	ret

;**********************************************************

CHPR:	
	sbr flags, 1<<MSGBSY
	bst flags, CHANN
	brts CHNL
	  sbr flags, 1<<CHANN	;Program
	  mov ch_no, cnt1
	  mov cnt1, pr_no
	  ldi temp1, $73	;'P'
	  com temp1
	  mov dig2, temp1
	  ldi temp1, $70	;'r'
	  com temp1
	  mov dig1, temp1
	ret
CHNL:	cbr flags, 1<<CHANN 	;Channel
	mov pr_no, cnt1
	mov cnt1, ch_no
	ldi temp1, $39		;'C'
	com temp1
	mov dig2, temp1
	ldi temp1, $74		;'h'
	com temp1
	mov dig1, temp1
	ret

;*********************************************************

BIN2BCD8:
	mov temp1, cnt1
	clr temp2
BBC1:	subi temp1, 10
	brcs BBC2
	inc temp2
	rjmp BBC1
BBC2:	subi temp1, -10
	ret 

;*********************************************************

PRINT:
	mov code, temp2
	rcall CHRGEN
	com char
	mov dig2, char
	mov code, temp1
	rcall CHRGEN
	com char
	mov dig1, char
	ret 	

;*********************************************************

STORE:	sbr flags, 1<<MSGBSY
	ldi temp1, $6d		;'S'
	com temp1
	mov dig2, temp1
	ldi temp1, $78		;'t'
	com temp1
	mov dig1, temp1 
	mov temp2, pr_no
	mov temp3, ch_no
	
EEWR:
	sbic EECR, EEWE
	rjmp EEWR
	out EEAR, temp2
	out EEDR, temp3
	sbi EECR, EEWE
	ret

;*********************************************************

EERD:
	sbic EECR, EEWE
	rjmp EERD
	out EEAR, temp2
	sbi EECR, EERE
	sbi EECR, EERE
	in temp3, EEDR
	cpi temp3, MAXCH+1
	brlo EER
	ldi temp3,21
EER:	ret

;*********************************************************

DELAY1:
	ldi temp1, $e0
	ldi temp2, $00
DL1:	inc temp2
	brne DL1
	inc temp1
	brne DL1
	ret	

;*********************************************************************

CALC:
	mov m2, ch_no
	cpi ch_no, 21
	brlo VHF3
	ldi temp1, 21
	sub m2, temp1
	ldi temp1, 128
	mov m1, temp1
	rcall MUL8
	ldi temp1, low(UHFBAS)
	ldi temp2, high(UHFBAS)
	add m1, temp1
	adc m2, temp2
	ldi temp1,0b00000100
	mov port3202, temp1
	ret
VHF3:  cpi ch_no, 05
	brlo VHF1
	ldi temp1, 05 
	sub m2, temp1
	ldi temp1, 112
	mov m1, temp1
	rcall MUL8
	ldi temp1, low(VHF3BAS)
	ldi temp2, high(VHF3BAS)
	add m1, temp1
	adc m2, temp2
	ldi temp1,0b00000010
	mov port3202, temp1
	ret
VHF1:  ldi temp1, 02
	sub m2, temp1
	ldi temp1, 112
	mov m1, temp1
	rcall MUL8 
	ldi temp1, low(VHF1BAS)
	ldi temp2, high(VHF1BAS)
	add m1, temp1
	adc m2, temp2
	ldi temp1, 0b00000001
	mov port3202, temp1
	ret

MUL8:
	mov temp4, m2
	clr m2
	clr temp1
	clr temp2
	clr temp3
MU3:	ror temp4
	brcc MU1
	add temp1, m1
	adc temp2, m2
MU1:	lsl m1
	rol m2
	cpi temp3, 7
	breq MU2
	inc temp3
	rjmp MU3
MU2:	mov m1, temp1
	mov m2, temp2
	ret	

;*********************************************************************

.def i2cadr = r17
.def i2cdata = r18
.def delay = r19

PLL:	
	;rcall I2C_INIT
	;ldi i2cadr, $c2
	mov i2cadr, plladdr
	rcall START
	mov i2cdata, m2
	rcall WRITE
	mov i2cdata, m1
	rcall WRITE
	ldi i2cdata, 0b10101110
	rcall WRITE
	mov i2cdata, port3202 ;ldi 0b00001011
	rcall WRITE
	rcall STOP
	ret

START:
	mov i2cdata, i2cadr
	sbi DDRD, SDAP
	rcall QP_DELAY
WRITE:
	sec
	rol i2cdata
	rjmp WRITE_FIRST
WRITE_BIT:
	lsl i2cdata
WRITE_FIRST:
	breq GET_ACK
	sbi DDRD, SCLP
	brcc WRITE_LOW
	nop
	cbi DDRD, SDAP
	rjmp WRITE_HIGH
WRITE_LOW:
	sbi DDRD, SDAP
	rjmp WRITE_HIGH
WRITE_HIGH:
	rcall HP_DELAY
	cbi DDRD, SCLP
	rcall HP_DELAY
	rjmp WRITE_BIT

GET_ACK:
	sbi DDRD, SCLP
	cbi DDRD, SDAP
	rcall HP_DELAY
	cbi DDRD, SCLP
ACK_WAIT:
	sbis PIND, SCLP
	rjmp ACK_WAIT
	clc
	sbic PIND, SDAP
	sec
	rcall HP_DELAY
	ret

HP_DELAY:
	ldi delay, 20
HP1:	dec delay
	brne HP1
	ret

QP_DELAY:
	ldi delay, 10
QP1:	dec delay
	brne QP1
	ret

STOP:
	sbi DDRD, SCLP
	sbi DDRD, SDAP
	rcall HP_DELAY
	cbi DDRD,SCLP
	rcall QP_DELAY
	cbi DDRD, SDAP
	rcall HP_DELAY
	ret


I2C_INIT:
	cbi PORTD, SCLP
	cbi PORTD, SDAP
	cbi DDRD, SCLP
	cbi DDRD, SDAP
	ret
;*********************************************************
	
RESET:	
	rcall INIT
	rcall CALC
	ldi plladdr, $c2
	rcall PLL

       ldi 	pr_no,1			;Set Program to 2
	mov 	temp2,pr_no
	rcall 	EERD			;Read channel of Program 2 from EEPROM
	mov 	ch_no,temp3
	mov cnt1,pr_no
       sbr 	flags,1<<CHANN		
       rcall 	CHPR	
	rcall CALC
	ldi plladdr, $c6
	rcall PLL

       
AGAIN:
	rcall SCAND
	rcall SCANK
	cpi key_no, 00
	breq MAIN1
	  clr timr1
	  clr timr2
	  bst flags,WUP
	  brtc WUP1
	  cbr flags,1<<WUP
	  mov key_rpt, key_no
	  sbr flags, 1<<NORPT
WUP1:	  rcall FUNCT
	rcall CALC
	ldi plladdr,$c6
	rcall PLL
MAIN1:	    bst flags, MSGBSY
	    brtc MAIN3
	    cpi cnt2, MSGBSYTM
	    brne MAIN2
	    rcall BIN2BCD8
	    rcall PRINT
	    cbr flags, 1<<MSGBSY
	    clr cnt2
	   rjmp MAIN3
MAIN2:	    inc cnt2	
MAIN3:	ldi temp1, $ff
	cp timr1, temp1
	breq TIM1
	inc timr1
	rjmp MAIN4
TIM1:	clr timr1
	ldi temp1, 6
	cp timr2, temp1
	breq TIM2
	inc timr2
MAIN4:	rcall DELAY1
	rjmp AGAIN

TIM2: 	andi scanr, 0b11111100
	sbr flags, 1<<WUP
	ldi temp1, $80
	com temp1
	out PORTB, temp1
	out PORTD, scanr
	ori scanr, 0b00000010
TIM3:	in temp2, PIND
	andi temp2, $0c
	cpi temp2, $0c
	brne MAIN4
	rjmp TIM3